Excelでガントチャートの矢印を自動作成する方法

以前、Excelでガントチャートを作成したい方向けに「Excelで時間単位・分単位のガントチャートを作成する方法」という記事を書きましたが、こちらは「開始時間と終了時間を入力すると、対応するセルが塗りつぶされる」というものでした。

Excelでガントチャートを作成したい方の中には、「セルを塗りつぶすのではなく、セルに矢印を表示したい」という方もいるでしょう。

そこで今回は、Excelでガントチャートの矢印を自動作成する方法をご紹介します。

なお、今回ご紹介する方法では「マクロ」を使います。マクロの作成方法や実行方法がよく分からない方は、まず先に以下の記事をご一読ください。

【VBA】Excelマクロとは？作り方から使い方までわかりやすく解説！

目次非表示

日付から矢印を自動作成する方法
範囲範囲に矢印を自動作成する方法
矢印の色や太さなどは自由にカスタマイズできる！
まとめ

目次へ

日付から矢印を自動作成する方法

まずはじめに、開始日と終了日を入力するとその日付に対応するセルに矢印が作成されるマクロをご紹介します。

コード

以下のコードをコピーして標準モジュールに貼り付けてください。

Sub 日付から矢印作成()

    Dim rng1 As Range
    Dim dt As Range
    Dim rng2 As Range
    Dim r As Long
    Dim foundCell1 As Range
    Dim startCol As Long
    Dim foundCell2 As Range
    Dim endCol As Long
    Dim targetRng As Range

    Set rng1 = ActiveSheet.Range(Range("C6"), Range("C6").End(xlToRight)) ' 日付入力範囲
    Set dt = ActiveSheet.Range("B4") ' 今日の日付入力セル
    
    For Each rng2 In ActiveSheet.Range(Range("A8"), Range("A8").End(xlDown)) ' 開始日入力範囲
        r = rng2.Row ' 開始日・終了日入力セルの行番号
        Set foundCell1 = rng1.Find(rng2, , xlFormulas, xlPart) ' 開始日で検索した時の該当セル
        startCol = foundCell1.Column ' 検索該当セルの列番号
            If rng2.Offset(0, 1) = "" Then ' 終了日が空欄の場合
                Set foundCell2 = rng1.Find(dt, , xlFormulas, xlPart)  ' 今日の日付で検索した時の該当セル
                endCol = foundCell2.Column '検索該当セルの列番号
            Else ' 終了日が空欄ではない場合
                Set foundCell2 = rng1.Find(rng2.Offset(0, 1), , xlFormulas, xlPart) ' 終了日で検索した時の該当セル
                endCol = foundCell2.Column '検索該当セルの列番号
            End If
        ActiveSheet.Range(Cells(r, startCol), Cells(r, endCol)).Select
        Set targetRng = Selection ' 開始日から終了日までのセル範囲
        With ActiveSheet.Shapes.AddLine(targetRng.Left, targetRng.Top + targetRng.Height / 2, _
            targetRng.Left + targetRng.Width, targetRng.Top + targetRng.Height / 2).Line
            .ForeColor.RGB = RGB(255, 0, 0) ' 線の色
            .Weight = 3 ' 線の太さ
            .EndArrowheadStyle = 2 ' 線の終点のスタイル
        End With
    Next rng2
    
End Sub

コードを貼り付けたら、マクロ実行ボタンに「日付から矢印作成」マクロを登録しましょう。

使い方

C6から右に連続した日付、B4に今日の日付（TODAY関数を使って表示）、A8から下に開始日、B8から下に終了日が入力されていると、「ガントチャートを作成」ボタンを押したとき、その期間に対応するセル範囲に赤い矢印が作成されます。開始日が空欄の場合矢印は作成されず、終了日が空欄の場合は今日の日付までを期間として矢印が作成されます。

範囲範囲に矢印を自動作成する方法

次に、選択範囲に矢印が作成されるマクロをご紹介します。

コード

以下のコードをコピーして標準モジュールに貼り付けてください。

Sub 選択範囲に矢印作成()
    
    Dim targetRng As Range
    
    Set targetRng = Selection ' 選択範囲
    
    With ActiveSheet.Shapes.AddLine(targetRng.Left, targetRng.Top + targetRng.Height / 2, _
        targetRng.Left + targetRng.Width, targetRng.Top + targetRng.Height / 2).Line
        .ForeColor.RGB = RGB(255, 0, 0) ' 線の色
        .Weight = 3 ' 線の太さ
        .EndArrowheadStyle = 2 ' 線の終点のスタイル
    End With
    
End Sub

コードを貼り付けたら、マクロ実行ボタンに「選択範囲に矢印作成」マクロを登録しましょう。